메뉴 건너뛰기

SAP 한국 커뮤니티

REPORT z17_18 .

sapjoy 2012.08.01 20:30 조회 수 : 2156

REPORT  z17_18                                 .

 

*----------------------------------------------------------------------*
*       CLASS lcl_handle_events DEFINITION
*----------------------------------------------------------------------*
class lcl_handle_events definition.
  public section.
    methods:
      on_link_click for event link_click of cl_salv_events_table
        importing row column.
endclass.                    "lcl_handle_events DEFINITION
*----------------------------------------------------------------------*
*       CLASS lcl_handle_events IMPLEMENTATION
*----------------------------------------------------------------------*
class lcl_handle_events implementation.
  method on_link_click.
    perform show_cell_info using row column 'Host spot 클릭하였습니다.'.
  endmethod.                    "on_double_click
endclass.                    "lcl_handle_events IMPLEMENTATION

data gt_itab    type table of sflight.
data gr_table   type ref to cl_salv_table.
data gr_event   type ref to lcl_handle_events.
data gr_columns type ref to cl_salv_columns_table.
data gr_column  type ref to cl_salv_column_table.

start-of-selection.

  select * from sflight into table gt_itab
  up to 25 rows.

  cl_salv_table=>factory(
    importing
      r_salv_table = gr_table
    changing
      t_table      = gt_itab ).

  gr_columns = gr_table->get_columns( ).
  gr_column ?= gr_columns->get_column( 'CARRID' ).
  gr_column->set_cell_type( if_salv_c_cell_type=>hotspot ).

  data lr_event type ref to cl_salv_events_table.
  lr_event = gr_table->get_event( ).

  create object gr_event.
  set handler gr_event->on_link_click for lr_event.

  gr_table->display( ).
*&---------------------------------------------------------------------*
*&      Form  SHOW_CELL_INFO
*&---------------------------------------------------------------------*
form show_cell_info using p_row    type i
                          p_column type lvc_fname
                          p_text   type string.

  data: l_row        type char10.

  write p_row to l_row left-justified.

  concatenate l_row '번째 라인의' p_column '컬럼을' p_text
  into p_text separated by space.

  message i000(0k) with p_text.

endform.                    " show_cell_info

번호 제목 글쓴이 날짜 조회 수
664 REPORT Z21_01 sapjoy 2015.10.28 1719
663 subroutine pool sapjoy 2013.11.15 2797
662 REPORT Z20_01. sapjoy 2012.08.01 4689
661 REPORT Z19_02. sapjoy 2012.08.01 3631
660 REPORT z19_01. sapjoy 2012.08.01 3252
659 REPORT z18_06. sapjoy 2012.08.01 2856
658 REPORT z18_05 sapjoy 2012.08.01 3057
657 REPORT z18_04 . sapjoy 2012.08.01 2982
656 REPORT z18_03. sapjoy 2012.08.01 2520
655 REPORT z18_02. sapjoy 2012.08.01 2753
654 REPORT z18_01. sapjoy 2012.08.01 2809
653 REPORT z17_23 sapjoy 2012.08.01 2268
652 REPORT z17_22 sapjoy 2012.08.01 2034
651 REPORT z17_21 . sapjoy 2012.08.01 2226
650 REPORT z17_20 sapjoy 2012.08.01 2615
649 REPORT z17_19 sapjoy 2012.08.01 2145
» REPORT z17_18 . sapjoy 2012.08.01 2156
647 REPORT z17_17 . sapjoy 2012.08.01 2001
646 REPORT z17_16 . sapjoy 2012.08.01 2060
645 REPORT z17_15 . sapjoy 2012.08.01 2266