>안녕하세요.

> 

>저도 질문하나 하도록 할께요... ^^

> 

>보통 SELECT-OPTION 에서 

> 

>[          ] TO [           ]      [x]<--- 다중입력 아이콘.

> 

>이렇게 화면을 구성하게되는데요.

> 

>머 첫화면에서 하는거야 자동 지원되니 문제가 없구요.

> 

>SELECT 화면이 아닌 다른 화면에서 INPUT 값 옆에 동일하게 [x] 다중입력 아이콘을 만들어서

> 

>동일하게 사용을 하려고 합니다.

> 

>알고 계신 방법있으시면 알려주세요 ^^  

> 

> 

가끔  모듈풀 프로그램에서 Selection-screen 에서처럼 from ~ to 값을 조건으로 사용하고자 할때

Screen에 만들어주기가 좀 모호할때가 있습니다.

그때는 지금 예제처럼 selection-screen 으로 서브스크린을 만들어 모듈풀 프로그램에 삽입하여

사용하면 편할 것 같아서 팁으로 만들어 봤습니다.

서브스크린은 SELECTION-SCREEN 사용법과 동일하게 사용하시면 됩니다.

예를들면, Enter 와 같은 이벤트로 화면 필드 점검을 하시려면 at selection-screen으로 하시면 됩니다.

[Source code] :

REPORT ztest.

TABLES vbap.

DATA : g_okcode    TYPE syucomm,
       g_vbeln     LIKE vbak-vbeln,  "" Screen field
       g_subscreen TYPE sydynnr.  "" SubScreen number

SELECTION-SCREEN BEGIN OF SCREEN 101 AS SUBSCREEN.
SELECTION-SCREEN SKIP 1.

SELECT-OPTIONS :
   so_posnr FOR vbap-posnr.
SELECTION-SCREEN END   OF SCREEN 101.

AT SELECTION-SCREEN.
  MESSAGE s001(cj) WITH 'Subscreen checked...!!'.

INITIALIZATION.
  g_subscreen = '0101'.

START-OF-SELECTION.

  CALL SCREEN 100.

*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'PF100'.
  SET TITLEBAR 'T100'.

ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  EXIT  INPUT
*&---------------------------------------------------------------------*
MODULE exit INPUT.
  LEAVE TO SCREEN 0.
ENDMODULE.                 " EXIT  INPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.

  CASE g_okcode.
    WHEN 'EXEC'.
      MESSAGE s001(cj) WITH 'Executed...!'.
  ENDCASE.

ENDMODULE.                 " USER_COMMAND_0100  INPUT

[Screen 100] :

[Flow-logic]

PROCESS BEFORE OUTPUT.
  MODULE status_0100.

  CALL SUBSCREEN subscreen101 INCLUDING sy-repid g_subscreen.
*
PROCESS AFTER INPUT.
  MODULE exit AT EXIT-COMMAND.

  CALL SUBSCREEN subscreen101.

  MODULE user_command_0100.

[Gui-Status PF100]:

   EXEC   -> Excute (F8)

   BACK   -> at exit command

자이 [ 2008.03.07 ] 저같은 경우는 온라인 프로그램을 모듈풀로 하지 않고 실행가능한 프로그램 Report 만들듯이 만들어 사용합니다. 오히려 이게 편하드라구요.

시골아이 [ 2008.02.25 ] 좋은 정보 감사합니다.^^

파워유저 [ 2007.11.27 ] 네..^^ 전 다른 뭔가가 있는 줄 았았네요..즐거운 하루 되세요.

타이 [ 2007.11.27 ] 온라인 레이아웃 구성하는 화면에서요... 왼쪽에 아이콘 중에 서브화면영역이라고 있을 겁니다... 고넘이예요.. 용어를 제가 맘대로 썼네요... ㅈㅅ

파워유저 [ 2007.11.27 ] 타이님 서브스크린 폼이 뭔가요?   출처 :  ABAPSCHOOL

타이 [ 2007.11.26 ] 다른 방법으로는요... 모듈풀 생성후 첫화면에 서브스크린 폼(이름을 head라하고)을 하나 만들어 처리를 합니다. SELECTION-SCREEN BEGIN OF SCREEN 0110 AS SUBSCREEN. PARAMETERS: P_KOKRS LIKE ZCOT0002-KOKRS OBLIGATORY. SELECTION-SCREEN END OF SCREEN 0110. -------------아래는 첫 화면 100에서 110(서브스크린)을 연결..... PROCESS BEFORE OUTPUT. MODULE STATUS_0100. CALL SUBSCREEN HEAD INCLUDING SY-REPID '0110'. * PROCESS AFTER INPUT. MODULE EXIT_COMMAND AT EXIT-COMMAND. CALL SUBSCREEN HEAD. MODULE USER_COMMAND_0100. " 요기서 실행버튼 실행..