급조로 필드 2개짜리 alv 를 예제로 만들었습니다.

event receiver 를 여기서 만드는 것으로 했기 때문에

그쪽에서 쓰시는 방법으로 선언만 하시면 될 거예요.

프로그램은 체크박스에 체크/언체크 시 value 필드에 1씩 값을 증가하게

했습니다.

도움이 되시길 바랍니다.

DATA g_okcode TYPE syucomm.

DATA : BEGIN OF gs_data,
         check1,
         value TYPE i,
       END   OF gs_data.
DATA gt_data   LIKE TABLE OF gs_data.
DATA gs_layout TYPE          lvc_s_layo.
DATA gt_fcat   TYPE lvc_t_fcat.
DATA g_grid    TYPE REF   TO cl_gui_alv_grid.
DATA g_stable  TYPE          lvc_s_stbl VALUE 'XX'.

START-OF-SELECTION.

  APPEND gs_data TO gt_data.

  CALL SCREEN 100.

*&---------------------------------------------------------------------*
*&      Module  STATUS  OUTPUT
*&---------------------------------------------------------------------*
MODULE status OUTPUT.
  SET PF-STATUS 'PF100'.
  SET TITLEBAR  'T100'.
ENDMODULE.                 " STATUS  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  EXIT  INPUT
*&---------------------------------------------------------------------*
MODULE exit INPUT.
  LEAVE TO SCREEN 0.
ENDMODULE.                 " EXIT  INPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND  INPUT
*&---------------------------------------------------------------------*
MODULE user_command INPUT.

  CASE g_okcode.
    WHEN ''.
    WHEN OTHERS.
  ENDCASE.

  CLEAR g_okcode.

ENDMODULE.                 " USER_COMMAND  INPUT
*&---------------------------------------------------------------------*
*&      Module  SET_GRID  OUTPUT
*&---------------------------------------------------------------------*
MODULE set_grid OUTPUT.

  IF g_grid IS NOT BOUND.

*   Create grid control
    CREATE OBJECT g_grid
      EXPORTING
        i_parent = cl_gui_container=>default_screen.

*   Set layout.
    gs_layout-cwidth_opt = 'X'.

*   Set field-catalog
    PERFORM set_fcat CHANGING gt_fcat.

*   Display grid
    g_grid->set_table_for_first_display(
      EXPORTING
        is_layout        = gs_layout
      CHANGING
        it_outtab        = gt_data
        it_fieldcatalog  = gt_fcat
    ).

*   Set grid-event
    PERFORM set_event_for_grid CHANGING g_grid.

  ELSE.
    g_grid->refresh_table_display( is_stable = g_stable ).
  ENDIF.

ENDMODULE.                 " SET_GRID  OUTPUT
*&---------------------------------------------------------------------*
*&      Form  SET_EVENT_FOR_GRID
*&---------------------------------------------------------------------*
FORM set_event_for_grid  CHANGING cl_grid TYPE REF TO cl_gui_alv_grid.

  DATA lcl_event TYPE REF TO zcl_km_event_receiver.

  CREATE OBJECT lcl_event.
  SET HANDLER lcl_event->handle_data_changed FOR cl_grid.

  cl_grid->register_edit_event(
      EXPORTING i_event_id = cl_grid->mc_evt_modified
  ).

ENDFORM.                    " SET_EVENT_FOR_GRID
*&---------------------------------------------------------------------*
*&      Form  handle_double_click
*&---------------------------------------------------------------------*
FORM handle_data_changed
   CHANGING sender          TYPE REF TO cl_gui_alv_grid
            er_data_changed TYPE REF TO cl_alv_changed_data_protocol
            e_onf4
            e_onf4_before
            e_onf4_after
            e_ucomm.

  FIELD-SYMBOLS : <lfs_mod_cell> TYPE lvc_s_modi,
                  <lfs_fcat>     TYPE lvc_s_fcat.

  READ TABLE er_data_changed->mt_mod_cells
             ASSIGNING <lfs_mod_cell>
                 INDEX 1.
  CHECK sy-subrc IS INITIAL.

  CLEAR gt_fcat.

  READ TABLE gt_data INTO gs_data INDEX <lfs_mod_cell>-row_id.
  IF sy-subrc IS INITIAL.
    ADD 1 TO gs_data-value.
    MODIFY gt_data FROM gs_data INDEX sy-tabix TRANSPORTING value.

    sender->refresh_table_display( is_stable = g_stable ).

  ENDIF.

ENDFORM.                    "handle_double_click
*&---------------------------------------------------------------------*
*&      Form  SET_FCAT
*&---------------------------------------------------------------------*
FORM set_fcat  CHANGING ct_fcat TYPE lvc_t_fcat.

  DATA ls_fcat TYPE lvc_s_fcat.

  CLEAR ls_fcat.
  ls_fcat-fieldname = 'CHECK1'.
  ls_fcat-checkbox  = 'X'.
  ls_fcat-edit      = 'X'.
  ls_fcat-coltext   = 'CheckBox 1'.
  ls_fcat-tooltip   = 'CheckBox 1'.
  ls_fcat-seltext   = 'CheckBox 1'.
  ls_fcat-outputlen = 10.
*
  APPEND ls_fcat TO ct_fcat.

  CLEAR ls_fcat.
  ls_fcat-fieldname = 'VALUE'.
  ls_fcat-checkbox  = ' '.
  ls_fcat-edit      = ' '.
  ls_fcat-coltext   = 'Value'.
  ls_fcat-tooltip   = 'Value'.
  ls_fcat-seltext   = 'Value'.
  ls_fcat-outputlen = 10.
  APPEND ls_fcat TO ct_fcat.

ENDFORM.                    " SET_FCAT