REPORT z15_09.

DATA : con1_ref    TYPE REF TO cl_gui_custom_container.
DATA : g_grid      TYPE REF TO cl_gui_alv_grid.
DATA : gt_emplist  TYPE TABLE OF zemplist.
DATA : gs_variant  TYPE disvariant.
DATA : gs_layout   TYPE lvc_s_layo.
DATA : gt_toolbar  TYPE ui_functions.
DATA : gt_sort  TYPE lvc_t_sort.
DATA : ok_code  TYPE sy-ucomm.

PARAMETERS: p_vari LIKE disvariant-variant.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_vari.
  gs_variant-report = sy-repid.
  CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
    EXPORTING
      is_variant    = gs_variant
      i_save        = 'A'
    IMPORTING
      es_variant    = gs_variant
    EXCEPTIONS
      not_found     = 1
      program_error = 2
      OTHERS        = 3.

  IF sy-subrc EQ 0.
    p_vari = gs_variant-variant.
  ENDIF.

START-OF-SELECTION.
  SELECT *
    FROM zemplist
    INTO TABLE @gt_emplist.

  CALL SCREEN 0100.

*&---------------------------------------------------------------------*
*&      Module  INIT_CON  OUTPUT
*&---------------------------------------------------------------------*
MODULE init_con OUTPUT.

  IF con1_ref IS INITIAL.
    CREATE OBJECT con1_ref
      EXPORTING
        container_name = 'CON1'.

    CREATE OBJECT g_grid
      EXPORTING
        i_parent = con1_ref.
  ENDIF.

  gs_variant-report = sy-repid.
  gs_variant-username = sy-uname.

  PERFORM setting_layout CHANGING gs_layout.
  PERFORM setting_toolbar.
  PERFORM setting_sort.

  CALL METHOD g_grid->set_table_for_first_display
    EXPORTING
      i_structure_name     = 'ZEMPLIST'
      is_variant           = gs_variant
      i_save               = 'A'
      i_default            = ''
      is_layout            = gs_layout
      it_toolbar_excluding = gt_toolbar
    CHANGING
      it_outtab            = gt_emplist
      it_sort              = gt_sort.

ENDMODULE.                 " INIT_CON  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
  IF ok_code = 'BACK'.
    LEAVE PROGRAM.
  ENDIF.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.

  SET PF-STATUS '100_STATUS'.
*  SET TITLEBAR 'xxx'.

ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Form  SETTING_LAYOUT
*&---------------------------------------------------------------------*
FORM setting_layout   CHANGING  p_layout TYPE lvc_s_layo.

  p_layout-cwidth_opt = ''.  "칼럼 길이 자동조절
  p_layout-grid_title = 'Sort Test'.  "타이틀 바
  p_layout-sel_mode   = 'B'.  "선택모드 : 멀티 선택 가능
  p_layout-zebra      = ''.  "Sripe 속성 지정

ENDFORM.                    " setting_layout
*&---------------------------------------------------------------------*
*&      Form  SETTING_TOOLBAR
*&---------------------------------------------------------------------*
FORM setting_toolbar .
  DATA: l_exclude TYPE ui_func.

  l_exclude =  cl_gui_alv_grid=>mc_fc_save_variant.
  APPEND l_exclude TO gt_toolbar.

  l_exclude = cl_gui_alv_grid=>mc_fc_maintain_variant.
  APPEND l_exclude TO gt_toolbar.

ENDFORM.                    " SETTING_TOOLBAR
*&---------------------------------------------------------------------*
*&      Form  SETTING_SORT
*&---------------------------------------------------------------------*
FORM setting_sort .
  DATA : ls_sort TYPE lvc_s_sort.

  ls_sort-spos      = '1'.
  ls_sort-fieldname = 'DEPCD'.
  ls_sort-up        = 'X'.
  ls_sort-subtot    = 'X'.
  APPEND ls_sort TO gt_sort.

ENDFORM.                    " SETTING_SORT