T-code: MB01를  BDC로 하면은 됩니다.

입고는 bapi를 주로 씁니다. BAPI_GOODSMVT_CREATE

참고로 new 계열 t-code들은 bdc가 힘들더라구요.

(migo나 me21n등..)

MIGO, MIRO와 T-code 뒤쪽에 N이 붙는 것은, SAP에서 enjoy인가 하는 프로젝트를 하면서 API 등으로 만들어 둔 것들이라 BDC가 안됩니다.

CJ20N, ME21N~23N 등등이 그런 것 입니다.

이전의 t-code인 MB01, MB1A~C 등을 활용하시거나 BAPI를 쓰시면 됩니다.

감사합니다.  MB01를 사용하여 해결되였습니다.

************************************************************************
*** 구매오더에 의한 입고처리
************************************************************************
*** 헤더 구성
DATA : st_goodsmvt_header   LIKE  bapi2017_gm_head_01,
       st_goodsmvt_code     LIKE  bapi2017_gm_code,
       st_goodsmvt_headret  LIKE  bapi2017_gm_head_ret,

*** 아이템 구성
       gt_goodsmvt_item LIKE bapi2017_gm_item_create OCCURS 0 WITH HEADER LINE,
       gt_goodsmvt_serialnumber LIKE bapi2017_gm_serialnumber OCCURS 0 WITH HEADER LINE,
       gt_return LIKE bapiret2 OCCURS 0 WITH HEADER LINE,

*** 생성전표/년도
       g_goodsmvt_doc       LIKE  bapi2017_gm_head_ret-mat_doc,
       g_materialdocument   LIKE  bapi2017_gm_head_ret-mat_doc,
       g_matdocumentyear    LIKE  bapi2017_gm_head_ret-doc_year.

************************************************************************
*** BAPI 를 통하여 건건이 입고처리 진행
************************************************************************
CLEAR : st_goodsmvt_header.    "<<---헤더 구조
CLEAR : g_goodsmvt_doc,        "<<---발생 전표
        g_materialdocument,    "<<---발생 전표
        g_matdocumentyear.     "<<---전표 년도

CLEAR : gt_goodsmvt_item[], gt_goodsmvt_item. "<<---아이템 정보구성
CLEAR : gt_return,          gt_return.        "<<---처리결과

*** 헤더 구성
st_goodsmvt_header-pstng_date   = gv_budat.   "<<---기표일자
st_goodsmvt_header-doc_date     = gv_bldat.   "<<---증빙일자
st_goodsvmt_header-header_txt   = gv_txt.     "<<---헤더텍스트
st_goodsmvt_code-gm_code        = '01'.       "<<---오더입고

*** 아이템구성
LOOP AT itab.
  IF itab-delivery_no IS NOT INITIAL.
    st_goodsmvt_header-ref_doc_no = itab-delivery_no.   "<<---납품문서(IN/OUTBOUND DELIVERY)
    gt_goodsmvt_item-deliv_numb   = itab-delivery_no.   "<<---납품문서(IN/OUTBOUND DELIVERY)
    gt_goodsmvt_item-deliv_item   = itab-delivery_item. "<<---납품순번
  ENDIF.

  gt_goodsmvt_item-po_number  = itab-ebeln.      "<<---발주번호
  gt_goodsmvt_item-po_item    = itab-ebelp.      "<<---발주품목
  gt_goodsmvt_item-move_type = '101'.            "<<---이동유형
  gt_goodsmvt_item-mvt_ind   = 'B'.              "<<---구매오더에 의한 입고
  gt_goodsmvt_item-material  = itab-matnr.       "<<---자재코드
  gt_goodsmvt_item-plant     = itab-werks_gr.    "<<---플랜트
  gt_goodsmvt_item-stge_loc  = itab-lgort_gr.    "<<---저장위치
  gt_goodsmvt_item-entry_qnt = itab-quantity.    "<<---입고할 수량
  APPEND gt_goodsmvt_item.
  CLEAR  gt_goodsmvt_item.
ENDLOOP.

*** 입고처리 실행
CALL FUNCTION 'BAPI_GOODSMVT_CREATE'
  EXPORTING
    goodsmvt_header  = st_goodsmvt_header
    goodsmvt_code    = st_goodsmvt_code
  IMPORTING
    goodsmvt_headret = st_goodsmvt_headret
    materialdocument = g_materialdocument
    matdocumentyear  = g_matdocumentyear
  TABLES
    goodsmvt_item    = gt_goodsmvt_item
    return           = gt_return.

IF NOT st_goodsmvt_headret IS INITIAL.
  CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
    EXPORTING
      wait = 'X'.
ELSE.
  CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
ENDIF.