*&---------------------------------------------------------------------*
*& Include          Z18_04_C01
*&---------------------------------------------------------------------*
CLASS lcl_tree_event DEFINITION.

  PUBLIC SECTION.
    CLASS-METHODS:
      handle_expand_no_children FOR EVENT expand_no_children
        OF cl_gui_list_tree
        IMPORTING node_key,

      handle_button_click FOR EVENT button_click
        OF cl_gui_list_tree
        IMPORTING node_key.
ENDCLASS.

CLASS lcl_tree_event IMPLEMENTATION.

  METHOD handle_expand_no_children.
    DATA:
      lt_node LIKE gt_node,
      lt_item LIKE gt_item.

    SELECT  a~empcd
           ,a~ename
           ,a~depcd
           ,CAST( COUNT( b~empcd ) AS CHAR( 20 ) ) AS count
      FROM zemplist AS a LEFT OUTER JOIN zfamily AS b
        ON a~empcd EQ b~empcd
      WHERE a~depcd EQ @node_key
      GROUP BY a~empcd , a~ename, a~depcd
      INTO TABLE @DATA(lt_data).

    LOOP AT lt_data INTO DATA(ls_data).

      APPEND VALUE #( node_key = ls_data-empcd
                      relatkey = ls_data-depcd
                      last_hitem = '1'
                      relatship = cl_gui_list_tree=>relat_last_child ) TO lt_node.

      APPEND VALUE #( node_key = ls_data-empcd
                      item_name = '1'
                      text = ls_data-ename
                      length = 10 )
        TO lt_item.

      APPEND VALUE #( node_key = ls_data-empcd
                      item_name = '2'
                      text = ls_data-count
                      alignment = cl_gui_list_tree=>align_center
                      class = cl_gui_list_tree=>item_class_button
                      length = 5 ) TO lt_item.
    ENDLOOP.


    CALL METHOD go_list_tree->add_nodes_and_items
      EXPORTING
        node_table                = lt_node
        item_table                = lt_item
        item_table_structure_name = 'MTREEITM'.

  ENDMETHOD.

  METHOD handle_button_click.

    SELECT  a~empcd
           ,b~ename
           ,a~fnum
           ,c~ddtext AS text
           ,a~fname
           ,a~bdate
      FROM zfamily  AS a LEFT OUTER JOIN
           zemplist AS b
        ON a~empcd EQ b~empcd
                         LEFT OUTER JOIN
           dd07t    AS c
        ON  c~domname    EQ 'ZDRELATION'
        AND c~ddlanguage EQ @sy-langu
        AND c~domvalue_l EQ a~relation
      WHERE a~empcd EQ @node_key
      ORDER BY a~fnum
      INTO CORRESPONDING FIELDS OF TABLE @gt_list.

    IF gt_list IS INITIAL.
      CLEAR gt_list.
    ENDIF.

    CALL METHOD go_alv_grid->set_frontend_layout
      EXPORTING
        is_layout = VALUE #( cwidth_opt = 'X' ).


    CALL METHOD go_alv_grid->refresh_table_display
      EXPORTING
        is_stable = VALUE #( row = 'X' col = 'X' ).

  ENDMETHOD.
ENDCLASS.