*&---------------------------------------------------------------------*
*& Include          Z18_03_O01
*&---------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*& Module STATUS_0100 OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE STATUS_0100 OUTPUT.
  SET PF-STATUS 'S0100'.
* SET TITLEBAR 'xxx'.
ENDMODULE.
*&---------------------------------------------------------------------*
*& Module COLUMN_TREE OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE COLUMN_TREE OUTPUT.

  IF GO_TREE_CONTAINER IS INITIAL.
    CREATE OBJECT GO_TREE_CONTAINER
      EXPORTING
        CONTAINER_NAME = 'TREE_AREA'.

    CREATE OBJECT GO_COLUMN_TREE
      EXPORTING
        PARENT                = GO_TREE_CONTAINER
        NODE_SELECTION_MODE   = CL_GUI_COLUMN_TREE=>NODE_SEL_MODE_SINGLE
        ITEM_SELECTION        = 'X'
        HIERARCHY_COLUMN_NAME = 'Column1'
        HIERARCHY_HEADER      = VALUE #( HEADING = '조직구조' WIDTH = 30 ).

    GT_NODE = VALUE #(
      ( NODE_KEY = 'Root' ISFOLDER = 'X' )  ).

    GT_ITEM = VALUE #(
      ( NODE_KEY = 'Root'   ITEM_NAME = 'Column1' TEXT = '부서' ) ).



    SELECT *
      FROM ZTEAMLIST
      ORDER BY DEPCD
      INTO TABLE @DATA(LT_TEAMLIST).

    LOOP AT LT_TEAMLIST INTO DATA(LS_TEAMLIST).

      APPEND VALUE #( NODE_KEY = LS_TEAMLIST-DEPCD
                      ISFOLDER = 'X'
                      RELATKEY = 'Root' ) TO GT_NODE.

      APPEND VALUE #( NODE_KEY = LS_TEAMLIST-DEPCD
                      ITEM_NAME = 'Column1'
                      TEXT = LS_TEAMLIST-DNAME ) TO GT_ITEM.
    ENDLOOP.


    SELECT *
      FROM ZEMPLIST
      WHERE DEPCD IS NOT INITIAL
      ORDER BY DEPCD, EMPCD
      INTO TABLE @DATA(LT_EMPLIST).

    LOOP AT LT_EMPLIST INTO DATA(LS_EMPLIST).
      APPEND VALUE #( NODE_KEY = LS_EMPLIST-EMPCD
                      ISFOLDER = SPACE
                      RELATKEY = LS_EMPLIST-DEPCD ) TO GT_NODE.

      APPEND VALUE #( NODE_KEY  = LS_EMPLIST-EMPCD
                      ITEM_NAME = 'Column1'
                      TEXT      = LS_EMPLIST-EMPCD ) TO GT_ITEM.

    ENDLOOP.

    CHECK GT_NODE IS NOT INITIAL.


    CALL METHOD go_column_tree->add_column
      EXPORTING
        name        = 'Column2'
        alignment   = cl_gui_column_tree=>align_left
        width       = 20
        header_text = '직원명'.

    LOOP AT lt_emplist INTO ls_emplist.

      APPEND VALUE #( node_key = ls_emplist-empcd
                      item_name = 'Column2'
                      text = ls_emplist-ename ) TO gt_item.
    ENDLOOP.

    CALL METHOD go_column_tree->add_column
      EXPORTING
        name        = 'Column3'
        alignment   = cl_gui_column_tree=>align_left
        width       = 20
        header_text = '보유 자격증 수'.

    SELECT  empcd
           ,CAST( COUNT( empcd ) AS CHAR( 20 ) ) AS count
      FROM zempcert
      GROUP BY empcd
      ORDER BY empcd
      INTO TABLE @DATA(lt_empcert).
*
    LOOP AT lt_empcert INTO DATA(ls_empcert).
      APPEND VALUE #( node_key = ls_empcert-empcd
                      item_name = 'Column3'
                      class = cl_gui_column_tree=>item_class_button
                      text = ls_empcert-count ) TO gt_item.
    ENDLOOP.



    CALL METHOD GO_COLUMN_TREE->ADD_NODES_AND_ITEMS
      EXPORTING
        NODE_TABLE                = GT_NODE
        ITEM_TABLE                = GT_ITEM
        ITEM_TABLE_STRUCTURE_NAME = 'MTREEITM'.



    CALL METHOD GO_COLUMN_TREE->SET_REGISTERED_EVENTS
      EXPORTING
        EVENTS = VALUE #(
        ( EVENTID = CL_GUI_COLUMN_TREE=>EVENTID_NODE_DOUBLE_CLICK
          APPL_EVENT = 'X' )
        ( EVENTID = CL_GUI_COLUMN_TREE=>EVENTID_BUTTON_CLICK
          APPL_EVENT = 'X' )
          ).

    DATA(LO_EVENT) = NEW LCL_TREE_EVENT( ).
    SET HANDLER: LO_EVENT->HANDLE_NODE_DOUBLE_CLICK FOR GO_COLUMN_TREE,
                 LO_EVENT->HANDLE_NODE_BUTTON_CLICK FOR GO_COLUMN_TREE.


  ENDIF.

ENDMODULE.
*&---------------------------------------------------------------------*
*& Module ALV OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE ALV OUTPUT.
  IF GO_ALV_CONTAINER IS INITIAL.

    CREATE OBJECT GO_ALV_CONTAINER
      EXPORTING
        CONTAINER_NAME = 'LIST_AREA'.

    CREATE OBJECT GO_ALV_GRID
      EXPORTING
        I_PARENT = GO_ALV_CONTAINER.

    CALL METHOD GO_ALV_GRID->SET_TABLE_FOR_FIRST_DISPLAY
      EXPORTING
        I_STRUCTURE_NAME = 'ZS18_02'
        IS_LAYOUT        = VALUE #( CWIDTH_OPT = 'X' )
      CHANGING
        IT_OUTTAB        = GT_LIST.
  ENDIF.

ENDMODULE.