*&---------------------------------------------------------------------*
*& Report Z09_02
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*

REPORT z09_02.

DATA: gt_list       TYPE TABLE OF zemplist,
      gt_dynpfields TYPE TABLE OF dynpread,
      gt_return_tab TYPE TABLE OF ddshretval.

PARAMETERS: p_depcd TYPE zteamlist-depcd,
            p_empcd TYPE zemplist-empcd,
            p_ename TYPE zemplist-ename.

INITIALIZATION.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_empcd.

  CALL FUNCTION 'DYNP_VALUES_READ'
    EXPORTING
      dyname             = sy-repid
      dynumb             = sy-dynnr
      translate_to_upper = 'X'
      request            = 'A'
    TABLES
      dynpfields         = gt_dynpfields.
  READ TABLE gt_dynpfields INTO DATA(gs_dynpfields)
    WITH KEY
      fieldname = 'P_DEPCD'.

  SELECT *
    FROM zemplist
    WHERE depcd EQ @gs_dynpfields-fieldvalue
    INTO CORRESPONDING FIELDS OF TABLE @gt_list.


  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
    EXPORTING
      ddic_structure  = 'ZEMPLIST'
      retfield        = 'EMPCD'
      dynpprog        = sy-repid
      dynpnr          = sy-dynnr
      dynprofield     = 'P_EMPCD'
      window_title    = 'Chapter 09 Search Help'
      value_org       = 'S'
    TABLES
      value_tab       = gt_list
*     FIELD_TAB       =
      return_tab      = gt_return_tab
    EXCEPTIONS
      parameter_error = 1
      no_values_found = 2
      OTHERS          = 3.

  CHECK gt_return_tab IS NOT INITIAL.

  READ TABLE gt_list INTO DATA(gs_list)
    WITH KEY
      empcd = VALUE #( gt_return_tab[ 1 ]-fieldval OPTIONAL ).

  DATA(lt_dynpread) = VALUE dynpread_t(
    ( fieldname = 'P_EMPCD' fieldvalue = gs_list-empcd )
    ( fieldname = 'P_ENAME' fieldvalue = gs_list-ename ) ).

  CALL FUNCTION 'DYNP_VALUES_UPDATE'
    EXPORTING
      dyname     = sy-repid
      dynumb     = sy-dynnr
    TABLES
      dynpfields = lt_dynpread.