프로그램 소스가 있는것두 아니고...;; 다운로드 부분만 올려달라는 말씀이신지...

어느정도의 답변을 원하시는지 잘모르겠습니다..

패턴눌러서 GUI_DOWNLOAD 처보시면...아실거 같은데요..

제가 얼마전 엑셀 다운로드에 관한 프로그램을 만들 때 참고 했던 선배의 자료입니다.

조금이라도 도움이 되셨으면 좋겠습니다.^^

REPORT  ZSDX_P021  NO STANDARD PAGE HEADING
                   LINE-SIZE 255
                   MESSAGE-ID ZSDX_MESSAGE.

INCLUDE <ICON>.

TABLES : ZSDX_EXPORT_M,
         ZSDX_LC_M,
         ZSDX_SALE_H,
         KNA1,
         PA0001.

DATA : BEGIN OF WA_LIST,
        MARK(1),      "U(수정), 공백(조회)
        SHIP_DT       LIKE ZSDX_EXPORT_M-SHIP_DT,      " 선적일자
        LC_NO         LIKE ZSDX_LC_M-LC_NO,            " LC번호
        ACCOUNT       LIKE ZSDX_EXPORT_M-ACCOUNT,      " 거래선코드
        NAME1         LIKE KNA1-NAME1,                 " 거래선명
        TOT_DELIV_CNT LIKE ZSDX_EXPORT_M-TOT_DELIV_CNT," 수량
        UNIT          LIKE ZSDX_EXPORT_M-UNIT,         " 단위
        AMT           LIKE ZSDX_EXPORT_M-AMT,          " 금액
        CURR_CD       LIKE ZSDX_EXPORT_M-CURR_CD,      " 통화
        DEPT_CD       LIKE ZSDX_EXPORT_M-DEPT_CD,      " 부서코드
        EMP_NO        LIKE ZSDX_EXPORT_M-EMP_NO,       " 사원번호
        SNAME         LIKE PA0001-SNAME,               " 사원명
        CHUL_NO1      LIKE ZSDX_EXPORT_M-CHUL_NO1,     " 오더번호
        CHUL_NO2      LIKE ZSDX_EXPORT_M-CHUL_NO2,     " 납품번호
        GOODS_GB      LIKE ZSDX_EXPORT_M-GOODS_GB,     " 제품구분
        COMMERCE_GB   LIKE ZSDX_EXPORT_M-COMMERCE_GB,  " 상품구분
        SAMPLE_YN     LIKE ZSDX_EXPORT_M-SAMPLE_YN,    " 무환여부
        LC_MANAGE_NO  LIKE ZSDX_EXPORT_M-LC_MANAGE_NO, " 관리번호
        LC_EXPORT_GB  LIKE ZSDX_EXPORT_M-LC_EXPORT_GB, " 수출구분
        MANAGE_SEQ    LIKE ZSDX_EXPORT_M-MANAGE_SEQ,   " 관리순번
        NOTSALE_REASON LIKE ZSDX_EXPORT_M-NOTSALE_REASON, "미매출사유
        CACCOUNT_TXT(34),
        CEMP_TXT(15),
        CLCMANAGENO_SEQ(15),
        CGOODS_TXT(6),
        CCOMMERCE_TXT(6),
       END OF WA_LIST.

DATA : BEGIN OF WA_DOWN,
        SHIP_DT(10),
        LC_NO(20),
        CACCOUNT_TXT(34),
        TOT_DELIV_CNT(20),
        UNIT(6),
        AMT(20),
        CURR_CD(6),
        DEPT_CD(6),
        CEMP_TXT(15),
        CHUL_NO1(10),
        CHUL_NO2(10),
        CGOODS_TXT(8),
        CCOMMERCE_TXT(8),
        CLCMANAGENO_SEQ(15),
        SAMPLE_TXT(8),
        NOTSALE_REASON(35),
       END OF WA_DOWN.

* 화면 분기용
DATA : BEGIN OF WA_TRANS,
         LC_MANAGE_NO LIKE ZSDX_ENTRY_M-LC_MANAGE_NO,
         LC_EXPORT_GB LIKE ZSDX_ENTRY_M-LC_EXPORT_GB,
         MANAGE_SEQ LIKE ZSDX_ENTRY_M-MANAGE_SEQ,
       END OF WA_TRANS.

DATA : IT_LIST LIKE TABLE OF WA_LIST,
       IT_DOWN LIKE TABLE OF WA_DOWN.

DATA : LAST_DATE LIKE SY-DATUM,
       ITMP_CNT TYPE I VALUE 1,
       CTMP_EMP(10),
       ILIN TYPE I,
       G_USERGROUP(100). "LIKE USGRP_USER-USERGROUP.

*-- SELECTION SCREEN
SELECTION-SCREEN BEGIN OF BLOCK BLK1 WITH FRAME TITLE TEXT-001.
SELECTION-SCREEN SKIP 1.
  SELECT-OPTIONS : P_SHIPDT FOR ZSDX_EXPORT_M-SHIP_DT NO-EXTENSION
                                                      OBLIGATORY,
                   P_DEPT FOR ZSDX_EXPORT_M-DEPT_CD.

SELECTION-SCREEN SKIP 1.
SELECTION-SCREEN END OF BLOCK BLK1.

*-- INITIALIZATION
INITIALIZATION.
  PERFORM SET_DATE.
  PERFORM GET_AUTH_GROUP.

*-- TOP OF PAGE
TOP-OF-PAGE.
  PERFORM TOP_OF_PAGE.

*-- START OF SELECTION
START-OF-SELECTION.
  PERFORM SET_MENU_TOOLBAR.
  PERFORM GET_DATA.

  DESCRIBE TABLE IT_LIST LINES ILIN.

  IF ILIN > 0.
    MESSAGE S007 WITH ILIN.
  ELSE.
    MESSAGE S008.
    LEAVE LIST-PROCESSING.
  ENDIF.

  PERFORM WRITE_DATA.

END-OF-SELECTION.

AT LINE-SELECTION.
  PERFORM CALL_PROGRAM.

AT USER-COMMAND.
  CASE SY-UCOMM.
    WHEN 'DOWN'.
      PERFORM EXCEL_DOWN.
    WHEN 'UPDA'.
      PERFORM UPDA_NOTSALE_REASON.
  ENDCASE.

*&---------------------------------------------------------------------*
*&      Form  SET_DATE
*&---------------------------------------------------------------------*
*       선적일자를 초기화한다. 해당달의 1일 ~ 마지막날
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM SET_DATE.
  CONCATENATE SY-DATUM+0(6) '01' INTO P_SHIPDT-LOW.

  CALL FUNCTION 'RP_LAST_DAY_OF_MONTHS'
  EXPORTING
    DAY_IN = SY-DATUM     "기준이 되는 임의의 일자
  IMPORTING
    LAST_DAY_OF_MONTH = LAST_DATE    "해당월의 마지막 일자
  EXCEPTIONS
    DAY_IN_NO_DATE = 1
    OTHERS = 2.

*  IF SY-SUBRC <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*   WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
*  ENDIF.

  P_SHIPDT-HIGH = LAST_DATE.

  APPEND P_SHIPDT.
ENDFORM.                    " SET_DATE

*&---------------------------------------------------------------------*
*&      Form  GET_DATA
*&---------------------------------------------------------------------*
*       LIST DATA를 DB에서 가져온다.
*----------------------------------------------------------------------*
*  -->  p1        text      text
*-----------
*  <--  p2  -----------------------------------------------------------*
FORM GET_DATA.
  CLEAR : WA_LIST.
  REFRESH : IT_LIST.

*-- 수출진행 DATA조회
  SELECT SHIP_DT ACCOUNT TOT_DELIV_CNT UNIT AMT CURR_CD DEPT_CD EMP_NO
         CHUL_NO1 CHUL_NO2 GOODS_GB COMMERCE_GB SAMPLE_YN
         NOTSALE_REASON LC_MANAGE_NO LC_EXPORT_GB MANAGE_SEQ
    INTO CORRESPONDING FIELDS OF WA_LIST
    FROM ZSDX_EXPORT_M
   WHERE SHIP_DT IN P_SHIPDT
     AND FORM_GB = '00'
     AND DEPT_CD IN P_DEPT.

*-- LC번호 조회
    SELECT SINGLE LC_NO
      INTO WA_LIST-LC_NO
      FROM ZSDX_LC_M
     WHERE LC_MANAGE_NO = WA_LIST-LC_MANAGE_NO
       AND LC_EXPORT_GB = WA_LIST-LC_EXPORT_GB.

*  -- 거래선명 조회
    SELECT SINGLE NAME1
      INTO WA_LIST-NAME1
      FROM KNA1
     WHERE KUNNR = WA_LIST-ACCOUNT.

    CONCATENATE '%' WA_LIST-EMP_NO '%' INTO CTMP_EMP.
*  -- 사원명 조회
    SELECT SINGLE SNAME
      INTO WA_LIST-SNAME
      FROM PA0001
     WHERE PERNR LIKE CTMP_EMP.

*  -- 제품구분 TEXT
    IF WA_LIST-GOODS_GB EQ '0'.
      WA_LIST-CGOODS_TXT = '자가'.
    ELSEIF WA_LIST-GOODS_GB EQ '1'.
      WA_LIST-CGOODS_TXT = '외주'.
    ENDIF.

*  -- 상품구분 TEXT
    IF WA_LIST-COMMERCE_GB EQ 'X'.
      WA_LIST-CCOMMERCE_TXT = '상품'.
    ELSE.
      WA_LIST-CCOMMERCE_TXT = '제품'.
    ENDIF.

*-- 거래선, 사원정보, 관리번호 TEXT
    SHIFT WA_LIST-ACCOUNT BY 5 PLACES.
    CONCATENATE WA_LIST-ACCOUNT WA_LIST-NAME1 INTO WA_LIST-CACCOUNT_TXT
                                                  SEPARATED BY SPACE.
    CONCATENATE WA_LIST-EMP_NO WA_LIST-SNAME INTO WA_LIST-CEMP_TXT
                                                  SEPARATED BY SPACE.
    CONCATENATE WA_LIST-LC_MANAGE_NO '-' WA_LIST-MANAGE_SEQ INTO
                                               WA_LIST-CLCMANAGENO_SEQ.

*-- 미매출내역을 구분한.(매출DATA가 있는 것을 제외한다.)
    SELECT SINGLE LC_MANAGE_NO
      FROM ZSDX_SALE_H
      INTO WA_LIST-LC_MANAGE_NO
     WHERE LC_MANAGE_NO = WA_LIST-LC_MANAGE_NO
       AND LC_EXPORT_GB = WA_LIST-LC_EXPORT_GB
       AND SALE_DT = WA_LIST-SHIP_DT
       AND DEPT_CD = WA_LIST-DEPT_CD
       AND CURR_CD = WA_LIST-CURR_CD.

    IF SY-SUBRC EQ '0'.
      CLEAR WA_LIST.
      CONTINUE.
    ELSE.
      APPEND WA_LIST TO IT_LIST.
      CLEAR WA_LIST.
    ENDIF.
  ENDSELECT.
ENDFORM.                    " GET_DATA
*&---------------------------------------------------------------------*
*&      Form  TOP_OF_PAGE
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM TOP_OF_PAGE.
*  WRITE: /1(170) '<   기선적 미 매출내역   >' CENTERED.
  SKIP.

  FORMAT COLOR COL_HEADING INTENSIFIED ON.
  WRITE: /1 SY-ULINE(255).
  WRITE: /1 SY-VLINE, (4) 'H' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (10) '선적일자' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (20) 'L/C번호' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (34) '고객사' CENTERED NO-GAP,
            SY-VLINE NO-GAP.
            SET LEFT SCROLL-BOUNDARY.
  WRITE:    (20) '수량' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (6)  '단위' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (17) '금액' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (6)  '통화' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (6)  '부서' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (16) '영업사원' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (10) '오더번호' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (10) '납품번호' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (10) '제품구분' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (10) '상품구분' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (8) '무환여부' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (15) '관리번호' CENTERED NO-GAP,
            SY-VLINE NO-GAP, (34) '비고' CENTERED NO-GAP,
            SY-VLINE NO-GAP.
  WRITE: /1 SY-ULINE(255).

ENDFORM.                    " TOP_OF_PAGE
*&---------------------------------------------------------------------*
*&      Form  WRITE_DATA
*&---------------------------------------------------------------------*
*       LIST DATA를 출력 처리한다.
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM WRITE_DATA.
  DATA C_COLOR(1).

  CLEAR WA_LIST.
  SORT IT_LIST BY SHIP_DT LC_NO.

  LOOP AT IT_LIST INTO WA_LIST.
    PERFORM SET_COLOR USING C_COLOR.
    WRITE : /1 SY-VLINE,
               (4) SY-TABIX RIGHT-JUSTIFIED NO-GAP,
               SY-VLINE NO-GAP,
               (10) WA_LIST-SHIP_DT USING EDIT MASK '____/__/__' NO-GAP,
               SY-VLINE NO-GAP,
               (20) WA_LIST-LC_NO NO-GAP,
               SY-VLINE NO-GAP,
               (34) WA_LIST-CACCOUNT_TXT NO-GAP,
               SY-VLINE NO-GAP,
               (20) WA_LIST-TOT_DELIV_CNT NO-GAP,
               SY-VLINE NO-GAP,
               (6) WA_LIST-UNIT CENTERED NO-GAP,
               SY-VLINE NO-GAP,
               (17) WA_LIST-AMT NO-GAP,
               SY-VLINE NO-GAP,
               (6) WA_LIST-CURR_CD CENTERED NO-GAP,
               SY-VLINE NO-GAP,
               (6) WA_LIST-DEPT_CD CENTERED NO-GAP,
               SY-VLINE NO-GAP,
               (8) WA_LIST-EMP_NO,
               (7) WA_LIST-SNAME NO-GAP,
               SY-VLINE NO-GAP,
               (10) WA_LIST-CHUL_NO1 NO-GAP,
               SY-VLINE NO-GAP,
               (10) WA_LIST-CHUL_NO2 NO-GAP,
               SY-VLINE NO-GAP,
               (10) WA_LIST-CGOODS_TXT CENTERED NO-GAP,
               SY-VLINE NO-GAP,
               (10) WA_LIST-CCOMMERCE_TXT CENTERED NO-GAP.

    IF WA_LIST-SAMPLE_YN EQ 'X'.
      WRITE : SY-VLINE NO-GAP, (8) ICON_OKAY AS ICON CENTERED NO-GAP.
    ELSE.
      WRITE : SY-VLINE NO-GAP, (8) ' '  NO-GAP.
    ENDIF.

    WRITE :    SY-VLINE NO-GAP,
               (15) WA_LIST-CLCMANAGENO_SEQ CENTERED NO-GAP,
               SY-VLINE NO-GAP.

*   매출담당자만 미매출 사유 입력가능 (JSM20061218)
    IF G_USERGROUP CS 'SDX41' OR G_USERGROUP CS 'SDX01'.
      WRITE : (34) WA_LIST-NOTSALE_REASON INPUT NO-GAP,
              SY-VLINE NO-GAP.
    ELSE.
      WRITE : (34) WA_LIST-NOTSALE_REASON NO-GAP,
              SY-VLINE NO-GAP.
    ENDIF.

    HIDE : WA_LIST-LC_MANAGE_NO, WA_LIST-LC_EXPORT_GB,
           WA_LIST-MANAGE_SEQ.
    WRITE : /1 SY-ULINE(255).
  ENDLOOP.
ENDFORM.                    " WRITE_DATA
*&---------------------------------------------------------------------*
*&      Form  EXCEL_DOWN
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM EXCEL_DOWN.
  CLEAR WA_DOWN.
  REFRESH IT_DOWN.

*-- HEADER
  WA_DOWN-SHIP_DT = '선적일자'.
  WA_DOWN-LC_NO = 'L/C번호'.
  WA_DOWN-CACCOUNT_TXT = '거래선'.
  WA_DOWN-TOT_DELIV_CNT = '수량'.
  WA_DOWN-UNIT = '단위'.
  WA_DOWN-AMT = '금액'.
  WA_DOWN-CURR_CD = '통화'.
  WA_DOWN-DEPT_CD = '부서'.
  WA_DOWN-CEMP_TXT = '영업사원'.
  WA_DOWN-CHUL_NO1 = '오더번호'.
  WA_DOWN-CHUL_NO2 = '납품번호'.
  WA_DOWN-CGOODS_TXT = '제품구분'.
  WA_DOWN-CCOMMERCE_TXT = '상품구분'.
  WA_DOWN-CLCMANAGENO_SEQ = '관리번호'.
  WA_DOWN-SAMPLE_TXT = '무환여부'.
  WA_DOWN-NOTSALE_REASON = '비고'.

  APPEND WA_DOWN TO IT_DOWN.

*-- CONTENTS
  LOOP AT IT_LIST INTO WA_LIST.
    MOVE-CORRESPONDING WA_LIST TO WA_DOWN.

    IF WA_LIST-SAMPLE_YN EQ 'X'.
       WA_DOWN-SAMPLE_TXT = '무환'.
    ENDIF.
    APPEND WA_DOWN TO IT_DOWN.
    CLEAR WA_DOWN.
  ENDLOOP.

  CALL FUNCTION 'Z_EXCEL_DOWNLOAD'
       EXPORTING
            FILENAME = '기선적미매출내역.XLS'
       TABLES
            DOWN_TAB = IT_DOWN
       EXCEPTIONS
            OTHERS   = 1.
ENDFORM.                    " EXCEL_DOWN
*&---------------------------------------------------------------------*
*&      Form  SET_MENU_TOOLBAR
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM SET_MENU_TOOLBAR.

* 미매출 사유 입력 권한 설정 추가(JSM20061218)
  IF G_USERGROUP CS 'SDX41' OR G_USERGROUP CS 'SDX01'.
    SET PF-STATUS 'MENU1000'.
  ELSE.
    SET PF-STATUS 'MENU1000' EXCLUDING 'UPDA'.
  ENDIF.

ENDFORM.                    " SET_MENU_TOOLBAR
*&---------------------------------------------------------------------*
*&      Form  SET_COLOR
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_C_COLOR  text
*----------------------------------------------------------------------*
FORM SET_COLOR USING    P_COLOR.

  IF P_COLOR IS INITIAL.
    FORMAT COLOR COL_NORMAL INTENSIFIED OFF. P_COLOR = 'X'.
  ELSE.
    FORMAT COLOR COL_NORMAL INTENSIFIED ON. CLEAR P_COLOR.
  ENDIF.

ENDFORM.                    " SET_COLOR
*&---------------------------------------------------------------------*
*&      Form  CALL_PROGRAM
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM CALL_PROGRAM.
  CLEAR WA_TRANS.

  WA_TRANS-LC_MANAGE_NO = WA_LIST-LC_MANAGE_NO.
  WA_TRANS-LC_EXPORT_GB = WA_LIST-LC_EXPORT_GB.
  WA_TRANS-MANAGE_SEQ = WA_LIST-MANAGE_SEQ.

  EXPORT WA_TRANS TO MEMORY ID 'ZSDXP014'.

  CALL TRANSACTION 'ZSDXP014'  AND SKIP FIRST SCREEN.
ENDFORM.                    " CALL_PROGRAM
*&---------------------------------------------------------------------*
*&      Form  GET_AUTH_GROUP
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM GET_AUTH_GROUP .

  IF G_USERGROUP IS INITIAL.
    DATA : C_GRP LIKE USGRP_USER-USERGROUP.
    SELECT USERGROUP INTO C_GRP FROM USGRP_USER
            WHERE BNAME = SY-UNAME.
      CONCATENATE G_USERGROUP C_GRP INTO G_USERGROUP
                  SEPARATED BY SPACE.
    ENDSELECT.
  ENDIF.

ENDFORM.                    " GET_AUTH_GROUP
*&---------------------------------------------------------------------*
*&      Form  UPDA_NOTSALE_REASON
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM UPDA_NOTSALE_REASON .
  CLEAR WA_LIST.

  PERFORM SET_SCREEN_ROW.

  LOOP AT IT_LIST INTO WA_LIST WHERE MARK = 'U'.

    UPDATE ZSDX_EXPORT_M SET NOTSALE_REASON = WA_LIST-NOTSALE_REASON
     WHERE LC_MANAGE_NO = WA_LIST-LC_MANAGE_NO
       AND LC_EXPORT_GB = WA_LIST-LC_EXPORT_GB
       AND MANAGE_SEQ   = WA_LIST-MANAGE_SEQ.

    IF SY-SUBRC NE '0'.
      ROLLBACK WORK.
      MESSAGE S013 WITH '미매출 사유 입력이 실패하였습니다.'.
      EXIT.
    ENDIF.

    CLEAR WA_LIST-MARK.
    MODIFY IT_LIST FROM WA_LIST TRANSPORTING MARK
                  WHERE LC_MANAGE_NO = WA_LIST-LC_MANAGE_NO
                    AND LC_EXPORT_GB = WA_LIST-LC_EXPORT_GB
                    AND MANAGE_SEQ   = WA_LIST-MANAGE_SEQ.

  ENDLOOP.

  IF SY-SUBRC EQ '0'.
    COMMIT WORK.
    MESSAGE S013 WITH '수정이 완료되었습니다.'.
  ELSE.
    MESSAGE S013 WITH '변경사항이 없습니다.'.
  ENDIF.

ENDFORM.                    " UPDA_NOTSALE_REASON
*&---------------------------------------------------------------------*
*&      Form  SET_SCREEN_ROW
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM SET_SCREEN_ROW.

  DATA : LC_NOTSALE_REASON(35),
         LC_LC_MANAGE_NO(12),
         LC_LC_EXPORT_GB(1),
         LC_MANAGE_SEQ(2).

  DO.
    CLEAR : LC_NOTSALE_REASON,
            LC_LC_MANAGE_NO,
            LC_LC_EXPORT_GB,
            LC_MANAGE_SEQ.

    READ LINE SY-INDEX FIELD VALUE WA_LIST-LC_MANAGE_NO
                                   WA_LIST-LC_EXPORT_GB
                                   WA_LIST-MANAGE_SEQ
                                   WA_LIST-NOTSALE_REASON.

    LC_LC_MANAGE_NO = WA_LIST-LC_MANAGE_NO.
    LC_LC_EXPORT_GB = WA_LIST-LC_EXPORT_GB.
    LC_MANAGE_SEQ = WA_LIST-MANAGE_SEQ.
    LC_NOTSALE_REASON = WA_LIST-NOTSALE_REASON.

    IF SY-SUBRC NE '0'.
      EXIT.
    ENDIF.

    CLEAR WA_LIST.

    READ TABLE IT_LIST INTO WA_LIST WITH KEY
                                    LC_MANAGE_NO = LC_LC_MANAGE_NO
                                    LC_EXPORT_GB = LC_LC_EXPORT_GB
                                    MANAGE_SEQ = LC_MANAGE_SEQ.

    CHECK SY-SUBRC EQ '0'.

    IF WA_LIST-NOTSALE_REASON NE LC_NOTSALE_REASON.
      WA_LIST-NOTSALE_REASON = LC_NOTSALE_REASON.
      WA_LIST-MARK = 'U'.
      MODIFY IT_LIST FROM WA_LIST TRANSPORTING MARK NOTSALE_REASON
                     WHERE LC_MANAGE_NO = LC_LC_MANAGE_NO
                       AND LC_EXPORT_GB = LC_LC_EXPORT_GB
                       AND MANAGE_SEQ = LC_MANAGE_SEQ.
    ENDIF.
  ENDDO.

ENDFORM.                    " SET_SCREEN_ROW

두분 답변 정말 감사드립니다 참고해서 열심히 해보겠습니다 꾸벅

난 내가 젤 힘든 줄 알았는데 다른 사람들이 훨씬 더 심하게 공부하는구나~

정보감사합니다! ^-^