우선 FIELD-SYMBOL 의 여러가지 변형을 살펴보면

  1. ASSIGN f TO <fs>.
      단순히 field f의 값을 <fs>가 가리키도록 한다.

  2. ASSIGN (f) TO <fs>.
      동적 field를 이용한것인데 field f안의 값을 또 field명으로 보고 그 field의 값
      을 <fs>가 가리키도록 한다.

  3. ASSIGN TABLE FIELD (f) TO <fs>.
      2와 같은 경우이나 f 의 값이 table의 field명 일때 그 table field의 값을 
      <fs>가 가리키도록 한다.

  4. ASSIGN LOCAL COPY OF MAIN TABLE FIELD (f) TO <fs>.
      3와 같은 경우이나 tables로 선언된 main program의 table field값을 
      <fs>가 가리키는 것이 아니라 값만 복사 하여 사용하기 때문에 변경할 수 없다. 

  5. ASSIGN COMPONENT idx OF STRUCTURE rec TO <fs>.
      structure의 구성요소 순서를 idx에서 읽어 그 순서에 위치한 구성요소의 값을
      <fs>에 할당한다. 

  6. ASSIGN COMPONENT name OF STRUCTURE rec TO <fs>.
      structure의 구성요소명(field명)을 name에서 읽어 그 구성요소의 값을
      <fs>에 할당한다. 

  5번을 제외한 모든 경우는 field명을 사용하는 것이라서 field명에 규칙이 없으면   
  coding line 줄이는데 효과를 보지 못한다.   
  따라서 여기서는 field명에 규칙이 없더라도 coding line을 획기 적으로 줄일 수 있는
  5번경우를 사용한 예제만 소개하겠다. 
   
예제)

 FIELD-SYMBOLS : <FS1>, <FS2>.
 DATA:IDX1 LIKE SY-INDEX.     

 DATA: BEGIN OF ITAB1 OCCURS 0,
        CCYYMM(8),
        WERKS LIKE MARD-WERKS,
        MATNR LIKE MARD-MATNR,
        LABST LIKE MARD-LABST,
        UMLME LIKE MARD-UMLME,
        INSME LIKE MARD-INSME,
        EINME LIKE MARD-EINME,
        SPEME LIKE MARD-SPEME,
        RETME LIKE MARD-RETME,
        VMLAB LIKE MARD-VMLAB,
        VMUML LIKE MARD-VMUML,
        VMINS LIKE MARD-VMINS,
        VMEIN LIKE MARD-VMEIN,
        VMSPE LIKE MARD-VMSPE,
        VMRET LIKE MARD-VMRET,
      END OF ITAB1.

 DATA: ITAB2 LIKE ITAB1 OCCURS 0 WITH HEADER LINE.   

경우1) FIELD-SYMBOL 사용하지 않았을 경우

 LOOP AT ITAB1.
    READ TABLE ITAB2 WITH KEY CCYYMM = ITAB1-PERIOD
                              WERKS  = ITAB1-WERKS
                              MATNR  = ITAB1-MATNR
                              BINARY SEARCH.
 
    IF SY-SUBRC <> 0. 
      WRITE : / 'Not found in ITAB2 : ',
                 ITAB1-CCYYMM,
                 ITAB1-WERKS,
                 ITAB1-MATNR.                 
    ELSE.
        IF ITAB1-LABST <> ITAB2-LABST.
          WRITE : / SY-INDEX,
                    ITAB2-CCYYMM,
                    ITAB2-WERKS,
                    ITAB2-MATNR,
                    ITAB1-LABST,
                    ITAB2-LABST.
        ENDIF.
 
        IF ITAB1-UMLME <> ITAB2-UMLME.
          WRITE : / SY-INDEX,
                    ITAB2-CCYYMM,
                    ITAB2-WERKS,
                    ITAB2-MATNR,
                    ITAB1-UMLME,
                    ITAB2-UMLME.
        ENDIF.
       

        .............. 12번 반복 ........

    ENDIF.
 ENDLOOP.

경우2) FIELD-SYMBOL 사용했을 경우

 LOOP AT ITAB1.
    READ TABLE ITAB2 WITH KEY CCYYMM = ITAB1-PERIOD
                              WERKS  = ITAB1-WERKS
                              MATNR  = ITAB1-MATNR
                              BINARY SEARCH.
 
    IF SY-SUBRC <> 0. 
      WRITE : / 'Not found in ITAB2 : ',
                 ITAB1-CCYYMM,
                 ITAB1-WERKS,
                 ITAB1-MATNR.                 
    ELSE.

      IDX1 = 3.
     
      DO 12 TIMES.
        IDX1 = IDX1 + 1.
        ASSIGN COMPONENT IDX1  OF STRUCTURE ITAB1 TO <FS1>.
        ASSIGN COMPONENT IDX1  OF STRUCTURE ITAB2 TO <FS2>.

        IF <FS1> <> <FS2>.
          WRITE : / SY-INDEX,
                    ITAB2-CCYYMM,
                    ITAB2-WERKS,
                    ITAB2-MATNR,
                    <FS1>,
                    <FS2>.
        ENDIF.
      ENDDO.
    ENDIF.
 ENDLOOP.