<img src=3.gif>전표 BDC 생성에 대한 질문입니다..

보경아빠 2010.01.26 16:58 조회 수 : 4868

고정환율 적용을 위해 FBV1으로 아래와 같이 코딩 했습니다..

그런데 코딩블럭 에서 다음 단계로 넘어가질 않네요...

( 일단 코딩블럭에 값은 정확히 들어 갑니다... 마우스로 OK 클릭하면 다음 단계로 진행됨 )

제가 뭘 잘 못했을까요? 고수님들 도움 부탁 드립니다..

loop at gt_dock.
IF sy-tabix = 1.
clear : lv_first, bdcdata[].

* 해당월의 마지막 일자 일자 구해서 lv_ldate에 저장

       PERFORM bdc_dynpro    USING 'SAPLF040'     '0100'.
       PERFORM bdc_field     USING 'BDC_CURSOR'   'RF05V-NEWKO'.
       PERFORM bdc_field     USING 'BDC_OKCODE'   '/00'.
       PERFORM bdc_field     USING 'BKPF-BLDAT'   lv_ldate.
       PERFORM bdc_field     USING 'BKPF-BUDAT'   lv_ldate.
       PERFORM bdc_field     USING 'BKPF-BLART'   'SA'.
       PERFORM bdc_field     USING 'BKPF-BUKRS'   p_kokrs.
       PERFORM bdc_field     USING 'BKPF-WAERS'   'USD'.
       PERFORM bdc_field     USING 'BKPF-BKTXT'   ' '.
       PERFORM bdc_field     USING 'VBKPF-XBWAE' ' '.
    ENDIF.

* 금액 변환
    perform currency_convert using gt_dock-wrbtr
                                      gt_dock-dmbtr
                                      lv_amtd
                                      lv_amtw.

    if gt_dock-shkzg   = 'S'.
       IF lv_first = 'X'.
          PERFORM bdc_dynpro   USING 'SAPLF040'      '0300'.
          PERFORM bdc_field    USING 'BDC_CURSOR'    'RF05V-NEWKO'.
          PERFORM bdc_field    USING 'BDC_OKCODE'    '/00'.
       ENDIF.

PERFORM bdc_field USING 'RF05V-NEWBS' '40'. "차변
PERFORM bdc_field USING 'RF05V-NEWKO' gt_dock-hkont.

       PERFORM bdc_dynpro      USING 'SAPLF040'      '0300'.
       PERFORM bdc_field       USING 'BDC_CURSOR'    'RF05V-NEWKO'.
       PERFORM bdc_field       USING 'BDC_OKCODE'    '/00'.
       PERFORM bdc_field       USING 'BSEG-WRBTR'    lv_amtd.
       PERFORM bdc_field       USING 'BSEG-DMBTR'    lv_amtw.
       PERFORM bdc_field       USING 'BSEG-ZUONR'    gt_dock-projk.
       PERFORM bdc_field       USING 'BSEG-SGTXT'    gt_dock-ktext.

       PERFORM bdc_dynpro      USING 'SAPLKACB'      '0002'.
       PERFORM bdc_field       USING 'BDC_CURSOR'    'COBL-PS_POSID'.
       PERFORM bdc_field       USING 'BDC_OKCODE'    '=ENTE'.
       PERFORM bdc_field       USING 'COBL-GSBER'    p_gsber.
       PERFORM bdc_field       USING 'COBL-KOSTL'    'DB005'.
       PERFORM bdc_field       USING 'COBL-PS_POSID' gt_dock-posid.   "<============여기서 멈춤
       lv_first = 'X'.
    else.
       IF lv_first = 'X'.
          PERFORM bdc_dynpro   USING 'SAPLF040'      '0300'.
          PERFORM bdc_field    USING 'BDC_CURSOR'    'RF05V-NEWKO'.
          PERFORM bdc_field    USING 'BDC_OKCODE'    '/00'.
       ENDIF.

PERFORM bdc_field USING 'RF05V-NEWBS' '50'. "차변
PERFORM bdc_field USING 'RF05V-NEWKO' gt_dock-hkont.

       PERFORM bdc_dynpro      USING 'SAPLF040'      '0300'.
       PERFORM bdc_field       USING 'BDC_CURSOR'    'BSEG-WRBTR'.

       PERFORM bdc_field       USING 'BDC_OKCODE'    '/00'.
       PERFORM bdc_field       USING 'BSEG-WRBTR'    lv_amtd.
       PERFORM bdc_field       USING 'BSEG-DMBTR'    lv_amtw.
       PERFORM bdc_field       USING 'BSEG-ZUONR'    '건조보험료'.
       PERFORM bdc_field       USING 'BSEG-SGTXT'    gt_dock-ktext.

       PERFORM bdc_dynpro      USING 'SAPLKACB'      '0002'.
       PERFORM bdc_field       USING 'BDC_CURSOR'    'COBL-GSBER'.
       PERFORM bdc_field       USING 'BDC_OKCODE'    '=ENTE'.
       PERFORM bdc_field       USING 'COBL-GSBER'    p_gsber.          "<============여기서 멈춤
       lv_first = 'X'.
    endif.

ENDLOOP.

이 게시물을

수정 삭제 목록

버미!

2010.01.27 07:52

지금 제가 구현한 내용이고요..정상적으로 전표가 생성므로 참고하세요..

CLEAR gt_bdcdata. REFRESH gt_bdcdata.
CLEAR gt_messtab. REFRESH gt_messtab.

DATA : l_wrbtr(15) TYPE c,
         l_mwsts(15) TYPE c.

* Header
CLEAR : l_wrbtr, l_mwsts.
WRITE gs_bkpf-wrbtr TO l_wrbtr
                  LEFT-JUSTIFIED CURRENCY gs_bkpf-waers.
WRITE gs_bkpf-mwsts TO l_mwsts
                 LEFT-JUSTIFIED CURRENCY gs_bkpf-waers.

PERFORM dynpro USING:
              'X' 'SAPLF040'               '0100',
              ' ' 'BDC_CURSOR'             'RF05V-NEWKO',
              ' ' 'BDC_OKCODE'             '/00',
              ' ' 'BKPF-BLDAT'             gs_bkpf-budat, "Doc.Date
              ' ' 'BKPF-BLART'             gs_bkpf-blart, "Doc.Type
              ' ' 'BKPF-BUKRS'             gs_bkpf-bukrs, "Comp.Code
              ' ' 'BKPF-BUDAT'             gs_bkpf-budat, "Posting Date
              ' ' 'BKPF-MONAT'             gs_bkpf-monat, "Period
              ' ' 'BKPF-WAERS'             gs_bkpf-waers, "Currency
              ' ' 'BKPF-XBLNR'             gs_bkpf-xblnr, "Reference
              ' ' 'BKPF-BKTXT'             gs_bkpf-bktxt, "Doc.Head.Txt

              ' ' 'RF05V-NEWBS'            gs_bkpf-bschl, "Posting Key
              ' ' 'RF05V-NEWKO'            gs_bkpf-hkont, "Account

              'X' 'SAPLF040'               '0302',
              ' ' 'BDC_CURSOR'             'RF05V-NEWKO',

              ' ' 'BDC_OKCODE'             '/00',
              ' ' 'BSEG-WRBTR'             l_wrbtr, "Amount
*              ' ' 'BSEG-WMWST'             l_mwsts, "Tax Amount
              ' ' 'BKPF-XMWST'             gs_bkpf-xmwst, "Cal.Tax Chk
              ' ' 'BSEG-MWSKZ'             gs_bkpf-mwskz, "Tax Code
              ' ' 'BSEG-ZTERM'             gs_bkpf-zterm, "PaytTerms
              ' ' 'BSEG-ZUONR'             gs_bkpf-xblnr, "Assignment
              ' ' 'BSEG-SGTXT'             gs_bkpf-sgtxt, "Text
              ' ' 'RF05V-NEWBS'            '40', "Posting Key
              ' ' 'RF05V-NEWKO'            '53310507'. "Account

* Item
LOOP AT gt_bseg.
    CLEAR : l_wrbtr.

    WRITE gt_bseg-wrbtr TO l_wrbtr
                   LEFT-JUSTIFIED CURRENCY gt_bseg-waers.

    PERFORM dynpro USING:
*                  ' ' 'RF05V-NEWBS'             gt_bseg-bschl, "P. Key
*                  ' ' 'RF05V-NEWKO'             gt_bseg-hkont, "Accot

                  'X' 'SAPLF040'               '0300',
                  ' ' 'BDC_CURSOR'             'BSEG-WRBTR',
                  ' ' 'BDC_OKCODE'             '/00',
                  ' ' 'BSEG-WRBTR'             l_wrbtr,       "Amount
                  ' ' 'BSEG-ZUONR'             gs_bkpf-xblnr, "Assignt
                  ' ' 'BSEG-SGTXT'             gs_bkpf-sgtxt, "Text
                  ' ' 'RF05V-NEWBS'            gt_bseg-bschl, "P. Key
                  ' ' 'RF05V-NEWKO'            gt_bseg-hkont. "Account

* More
    PERFORM dynpro USING:
                  'X' 'SAPLKACB'               '0002',
                  ' ' 'BDC_CURSOR'             'COBL-KDPOS',
                  ' ' 'BDC_OKCODE'             '=COBL_XERGO',
                  ' ' 'COBL-KDAUF'             gs_bkpf-aubel, "S/O No
                  ' ' 'COBL-KDPOS'             gs_bkpf-aupos. "S/O Item

* Get CO Info
    PERFORM get_co_info USING gt_bseg-vbeln gt_bseg-posnr.

    PERFORM dynpro USING:
                  'X' 'SAPLKEAK'               '0300',
                  ' ' 'BDC_CURSOR'             'RKEAK-FIELD(15)',
                  ' ' 'BDC_OKCODE'             '=P+',
                  ' ' 'RKEAK-FIELD(01)'        gs_co-kndnr, "Customer
                  ' ' 'RKEAK-FIELD(02)'        gs_co-artnr, "Product
                  ' ' 'RKEAK-FIELD(03)'        gs_co-fkart, "B.Type
                  ' ' 'RKEAK-FIELD(07)'        gs_co-werks, "Plant
                  ' ' 'RKEAK-FIELD(08)'        gs_co-vkorg, "S.Org
                  ' ' 'RKEAK-FIELD(09)'        gs_co-vtweg, "Distr.Ch
                  ' ' 'RKEAK-FIELD(10)'        gs_co-spart, "Division
                  ' ' 'RKEAK-FIELD(13)'        gs_co-prctr, "P. Cent.
                  ' ' 'RKEAK-FIELD(15)'        gs_co-auart, "S/O Type

                  'X' 'SAPLKEAK'               '0300',
                  ' ' 'BDC_CURSOR'             'RKEAK-FIELD(14)',
                  ' ' 'BDC_OKCODE'             '=WEIT',
                  ' ' 'RKEAK-FIELD(01)'        gs_co-brsch, "Industry
                  ' ' 'RKEAK-FIELD(02)'        gs_co-bzirk, "S. distr.
                  ' ' 'RKEAK-FIELD(03)'        gs_co-kmland, "Country
                  ' ' 'RKEAK-FIELD(04)'        gs_co-kmvtnr, "S.Emplo.
                  ' ' 'RKEAK-FIELD(05)'        gs_co-matkl, "Mat.Grp
                  ' ' 'RKEAK-FIELD(06)'        gs_co-mtart, "Mat. Type
                  ' ' 'RKEAK-FIELD(07)'        gs_co-vkbur, "S.Office
                  ' ' 'RKEAK-FIELD(08)'        gs_co-vkgrp, "S.Group
                  ' ' 'RKEAK-FIELD(09)'        gs_co-ww040, "Ori.S.OTy
                  ' ' 'RKEAK-FIELD(10)'        gs_co-ww050, "Region1
                  ' ' 'RKEAK-FIELD(11)'        gs_co-ww001, "Primy/Seco
                  ' ' 'RKEAK-FIELD(12)'        gs_co-ww010, "Steel Grd
                  ' ' 'RKEAK-FIELD(13)'        gs_co-ww020, "Surface
                  ' ' 'RKEAK-FIELD(14)'        gs_co-ww030. "Thickness

* More
    PERFORM dynpro USING:
                  'X' 'SAPLKACB'               '0002',
                  ' ' 'BDC_CURSOR'             'COBL-GSBER',
                  ' ' 'BDC_OKCODE'             '=ENTE',
*                ' ' 'COBL-GSBER'             '2615',
                  ' ' 'COBL-PRCTR'             gs_co-prctr,
                  ' ' 'COBL-KDAUF'             gs_bkpf-aubel, "S/O No
                  ' ' 'COBL-KDPOS'             gs_bkpf-aupos. "S/O Item
ENDLOOP.

* Save
PERFORM dynpro USING:
                'X' 'SAPLF040'               '0300',
                ' ' 'BDC_CURSOR'             'BSEG-WRBTR',
                ' ' 'BDC_OKCODE'             '=BP'.

PERFORM dynpro USING:
                'X' 'SAPLKACB'               '0002',
                ' ' 'BDC_CURSOR'             'COBL-GSBER',
                ' ' 'BDC_OKCODE'             '/EENTE',
*                ' ' 'COBL-GSBER'             '2615',
                ' ' 'COBL-PRCTR'             gs_co-prctr,
                ' ' 'COBL-KDAUF'             gs_bkpf-aubel, "S/O No
                ' ' 'COBL-KDPOS'             gs_bkpf-aupos. "S/O Item

REFRESH gt_messtab.

g_ctu_params-dismode = 'E'.

CALL TRANSACTION 'FBV1' USING   gt_bdcdata
                          OPTIONS FROM g_ctu_params
                          MESSAGES INTO gt_messtab.

댓글 수정 삭제
보경아빠

2010.01.28 18:56

버미님 감사합니다...
아래처럼 했더니 일단 전표는 들어가네요... ^^;

* Header
clear bdcdata. refresh bdcdata.

PERFORM bdc_dynpro USING 'SAPLF040' '0100'.
PERFORM bdc_field USING 'BDC_CURSOR' 'RF05V-NEWKO'.
PERFORM bdc_field USING 'BDC_OKCODE' '/00'.
PERFORM bdc_field USING 'BKPF-BLDAT' lv_ldate.
PERFORM bdc_field USING 'BKPF-BUDAT' lv_ldate.
PERFORM bdc_field USING 'BKPF-BLART' 'SA'.
PERFORM bdc_field USING 'BKPF-BUKRS' p_kokrs.
PERFORM bdc_field USING 'BKPF-WAERS' 'USD'.
PERFORM bdc_field USING 'BKPF-BKTXT' ' '.
PERFORM bdc_field USING 'VBKPF-XBWAE' ' '.

* Item
LOOP AT gt_dock.
WRITE gt_dock-wrbtr to lv_amtd left-justified currency 'USD'.
WRITE gt_dock-dmbtr to lv_amtw left-justified currency 'KRW'.

IF lv_first = 'X'.
PERFORM bdc_dynpro USING 'SAPLF040' '0330'.
PERFORM bdc_field USING 'BDC_CURSOR' 'RF05V-NEWKO'.
PERFORM bdc_field USING 'BDC_OKCODE' '/00'.
ENDIF.

PERFORM bdc_field USING 'RF05V-NEWBS' gt_dock-bschl. "40/50
PERFORM bdc_field USING 'RF05V-NEWKO' gt_dock-hkont.

PERFORM bdc_dynpro USING 'SAPLF040' '0300'.
PERFORM bdc_field USING 'BDC_CURSOR' 'BSEG-WRBTR'.
PERFORM bdc_field USING 'BDC_OKCODE' '=ZK'.
PERFORM bdc_field USING 'BSEG-WRBTR' lv_amtd.
PERFORM bdc_field USING 'BSEG-DMBTR' lv_amtw.
PERFORM bdc_field USING 'BSEG-ZUONR' gt_dock-zuonr. "40:공사번호, 50:건조보험료
PERFORM bdc_field USING 'BSEG-SGTXT' gt_dock-ktext.
PERFORM bdc_field USING 'RF05V-NEWBS' gt_dock-bschl. "40/50
PERFORM bdc_field USING 'RF05V-NEWKO' gt_dock-hkont. "C/E

PERFORM bdc_dynpro USING 'SAPLKACB' '0002'.
PERFORM bdc_field USING 'BDC_CURSOR' 'COBL-GSBER'.
PERFORM bdc_field USING 'BDC_OKCODE' '=ENTE'.
PERFORM bdc_field USING 'COBL-GSBER' p_gsber.

if gt_dock-hkont <> '1119361100'.
PERFORM bdc_field USING 'COBL-KOSTL' 'DB005'.
PERFORM bdc_field USING 'COBL-PS_POSID' gt_dock-posid.
endif.

lv_first = 'X'.

ENDLOOP.

댓글 수정 삭제

번호	제목	글쓴이	날짜	조회 수
188	<b>[완료]</b>팝업창에서 메시지를 두줄로 쓰는게 가능한가요. [5]	대략나	2008.02.18	4644
187	<img src=2.gif>SET UPDATE TASK LOCAL <- 관해 문의드립니다. [2]	맹꽁이	2009.12.01	4646
186	[요청]VL31N 화면을 통한 인바운드납품 처리하는 BAPI로 GN_DELIVERY_CREATE 사용하려합니다. [2]	넷가이	2008.10.07	4651
185	온라인프로그램에 두개의 컨테이너를 지정후 alv 적용 아시는 분? [1]	노력&성장	2007.08.19	4681
184	<b>[완료]</b>[질문]4개이상의 TABLE INNER JOIN 방법 [5]	아싸ㅎ	2008.04.03	4687
183	[요청]loop 안에 if문에서 걸렸을때 loop까지 한번에 빠져나오려면?? [5]	bizarre	2008.11.10	4692
182	<img src=2.gif>AT SELECTION-SCREEN OUTPUT. 질분입니다 [3]	아밥콩`	2010.06.17	4705
181	<img src=2.gif>ALV에서 년월 필드 사용에 대해 [4]	댕댕	2010.04.21	4728
180	[요청]SELECT~ENDSELECT 문에서 문의드립니다. [2]	풍뎅이	2007.12.12	4738
179	[요청]delete 하는법 알려주세요...조건에 맞는필드를 삭제하려고요... [5]	아밥!	2008.11.06	4744
178	<b>[완료]</b>SUBMIT 또는 CALL TRANSACTION 에 관해서... [5]	chanmaniac	2008.09.29	4752
177	<b>[완료]</b>엑셀업로드시 데이터건수제한에 대해서 질문드립니다. [3]	kan145	2009.03.24	4763
176	<img src=3.gif>alv 필드 오른쪽 정렬에 대해서 질문 좀 드릴게요 [3]	유정a	2010.08.23	4770
175	<img src=3.gif>스마트 폼에서 그래픽 출력할때 이상합니다. [3]	이소아밀	2011.03.31	4785
174	<img src=3.gif>금액 절사방법에 대해 질문드립니다. [6]	해바라기	2009.11.19	4794
173	null 값 체크 [6]	강진규	2007.05.21	4813
172	<b>[완료]</b><b>[완료]</b>[re] 개인pc에 SAP NetWeaver 2004s 설치방법에 질문입니다. [1]	김태완	2006.12.27	4829
171	<img src=1.gif>질문 >> CALL FUNCTION 'FIMA_NUMERICAL_VALUE_ROUND [2]	아밥콩`	2010.03.03	4848
170	<b>[완료]</b>DYNPRO_FIELD_CONVERSION dump관련 [3]	이정한	2008.01.08	4855
»	<img src=3.gif>전표 BDC 생성에 대한 질문입니다.. [2]	보경아빠	2010.01.26	4868

쓰기 태그

첫 페이지 312 313 314 315 316 317 318 319 320 321 끝 페이지

SAP 한국 커뮤니티

로그인

<img src=3.gif>전표 BDC 생성에 대한 질문입니다..

댓글 2

버미!

보경아빠