조회화면에서 만든거구요 

혹시 예시같은거있나요 

-----------------예시는 만들면 됩니다.

REPORT ZABC.

TABLES: sscrfields.
DATA: gt_l1 TYPE vrm_values,
      gt_l2 TYPE vrm_values.

CONSTANTS: gc_l1_name TYPE vrm_id VALUE 'P_L1',
           gc_l2_name TYPE vrm_id VALUE 'P_L2'.

*--------------------------------------------------------------------*
*P_R1 선택시 p_l1 = A, B, C
*P_R2 선택시 p_l1 = X, Y, Z
*
*P_L1 A 선택시 p_l2 = 1, 2, 3
*P_L1 B 선택시 p_l2 = 4, 5, 6
*P_L1 C 선택시 p_l2 = 7, 8, 9
*--------------------------------------------------------------------*

PARAMETERS: p_r1 RADIOBUTTON GROUP r1 DEFAULT 'X' USER-COMMAND r1,
            p_r2 RADIOBUTTON GROUP r1,
            p_l1 AS LISTBOX VISIBLE LENGTH 10 USER-COMMAND l1,
            p_l2 AS LISTBOX VISIBLE LENGTH 10 USER-COMMAND l2.

INITIALIZATION.
  gt_l1 = VALUE #( ( key = 'A'  text = '에이' )
                   ( key = 'B'  text = '비' )
                   ( key = 'C'  text = '씨' ) ).

  CALL FUNCTION 'VRM_SET_VALUES'
    EXPORTING
      id     = gc_l1_name
      values = gt_l1.



AT SELECTION-SCREEN.
  CASE sscrfields-ucomm.

    WHEN 'R1'.
      IF p_r1 = 'X'.
        gt_l1 = VALUE #( ( key = 'A'  text = '에이' )
                         ( key = 'B'  text = '비' )
                         ( key = 'C'  text = '씨' ) ).
      ELSEIF p_r2 = 'X'.
        gt_l1 = VALUE #( ( key = 'X'  text = '엑스' )
                         ( key = 'Y'  text = '와이' )
                         ( key = 'Z'  text = '제트' ) ).
      ENDIF.

      CALL FUNCTION 'VRM_SET_VALUES'
        EXPORTING
          id     = gc_l1_name
          values = gt_l1.

    WHEN 'L1'.
      CLEAR p_l2.

      CASE p_l1.
        WHEN 'A'.
          gt_l2 = VALUE #( ( key = '1'  text = '일' )
                           ( key = '2'  text = '이' )
                           ( key = '3'  text = '삼' ) ).
        WHEN 'B'.

          gt_l2 = VALUE #( ( key = '4'  text = '사' )
                           ( key = '5'  text = '오' )
                           ( key = '6'  text = '육' ) ).
        WHEN 'C'.
          gt_l2 = VALUE #( ( key = '7'  text = '칠' )
                           ( key = '8'  text = '팔' )
                           ( key = '9'  text = '구' ) ).
      ENDCASE.

      CALL FUNCTION 'VRM_SET_VALUES'
        EXPORTING
          id     = gc_l2_name
          values = gt_l2.

    WHEN 'L2'.
      "DO WHAT YOU WANT TO DO

  ENDCASE.

근데 첫번째 listbox도 라디오버튼에 따라서 다른 list를 뿌리는데 

INITIALIZATION에 들어가도 되나요